Query histogram and summary metrics

Unlike other OpenTelemetry (OTel) metric types, a histogram or summary metric doesn't hold a single measurement. Each one carries several components that mean different things, such as an observation count alongside a distribution. Query these metric types with a function that's aware of that shape, or by selecting the component you want.

Histogram metrics

Query histogram metrics with bucket and an interpolate_ function: interpolate_cumulative_histogram for cumulative temporality, interpolate_delta_histogram for delta temporality. Use them when you want the observation count, the average, or an estimated quantile such as the 90th percentile. For the syntax, see Bucket. For examples, see Sample MPL queries.

Summary metrics

MPL has no interpolate_ function for summaries because the producer already computed the quantiles. Instead, select the component you want with the reserved axiom.summary and axiom.quantile tags, and derive anything else with compute.

Count and sum

Filter to the component you want.

`my-metrics`:`service.request.duration`
| where `service.name` == "checkout"
| where `axiom.summary` == "count"
| align to 5m using sum

`my-dataset`:`service.request.duration`
| where `service.name` == "checkout"
| where `axiom.summary` == "sum"
| align to 5m using sum

Average

Divide the sum component by the count component with compute.

(
  `my-dataset`:`service.request.duration`
  | where `service.name` == "checkout"
  | where `axiom.summary` == "sum"
  | group using sum,
  `my-dataset`:`service.request.duration`
  | where `service.name` == "checkout"
  | where `axiom.summary` == "count"
  | group using sum
)
| compute average using /

Minimum and maximum

If the producer emits the 0.0 and 1.0 quantiles, use them as the minimum and the maximum.

// Minimum
`my-dataset`:`service.request.duration`
| where `service.name` == "checkout"
| where `axiom.summary` == "bucket" and `axiom.quantile` == 0.0

// Maximum
`my-dataset`:`service.request.duration`
| where `service.name` == "checkout"
| where `axiom.summary` == "bucket" and `axiom.quantile` == 1.0

Quantiles

A summary only contains the quantiles the producer computed. You can select one of them, but you can't derive a quantile that isn't there.

// Median, if the producer emits the 0.5 quantile
`my-dataset`:`service.request.duration`
| where `service.name` == "checkout"
| where `axiom.summary` == "bucket" and `axiom.quantile` == 0.5